2025-01-31 23:11:16+00:00grafted

3 files changed, 75 insertions, 0 deletions

diff --git a/dev-python/github3-py/Manifest b/dev-python/github3-py/Manifest
new file mode 100644
index 0000000000000..2567262001cce
--- /dev/null
+++ b/dev-python/github3-py/Manifest
@@ -0,0 +1,3 @@
+DIST github3.py-4.0.1.tar.gz 36214038 BLAKE2B 04647fd53b0ad236891bb0fab359a326d82f8fb90c186618459013ab32f7c7c148374ad0dfc891220b839b2d9be7231e15dac8048bd767c33a1513558b3b16d1 SHA512 a79f7e4c48405318bd61d03c7a8b2dc3629f6e2d8e954e316fba319115dd12c6e5e2fd69a00743e86078367b083841dbc494704e66ffda8582fb48c614ecf5b2
+EBUILD github3-py-4.0.1.ebuild 1295 BLAKE2B e69efccd6b4bb8e86075b948645da9d2569ea1c4ffead9ebfddb1c944cfdd52c6003be181af73fe77fa0c589f876c9f06bea37fb014c0eb921415ae1e5541dcb SHA512 7126375dee6356493ba523cc69d7d9ab28da9212e9e6fda3f62d1090245f018dea60153ee5b65175a3d9fd473a682d2db441cf3eceb42e5ac841094ab6f26fc5
+MISC metadata.xml 675 BLAKE2B aa0bec874cc285c1d5eb57c128188c8690eb572191465ac193e8df40836b4b27b1994916ee419c2d03e7fd95ad6ee2882d5b603702939663bedc9a0a27f7aeb0 SHA512 cc6cceaf8fb98df0ff61aa8ed7e45af8054cc20ea7e6697ff30d103d2dc5b479486374ad6f99e4de46cc37214701fbfaa4d3fd1a74923b9e7d7dfddae08ebcf8
diff --git a/dev-python/github3-py/github3-py-4.0.1.ebuild b/dev-python/github3-py/github3-py-4.0.1.ebuild
new file mode 100644
index 0000000000000..badec0cfd46e3
--- /dev/null
+++ b/dev-python/github3-py/github3-py-4.0.1.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYPI_NO_NORMALIZE=1
+PYPI_PN=${PN/-/.}
+PYTHON_COMPAT=( python3_{10..13} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="A wrapper for the GitHub API written in python"
+HOMEPAGE="
+	https://github.com/sigmavirus24/github3.py/
+	https://pypi.org/project/github3.py/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	dev-vcs/git
+	>=dev-python/pyjwt-2.3.0[${PYTHON_USEDEP}]
+	>=dev-python/python-dateutil-2.6.0[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.18[${PYTHON_USEDEP}]
+	>=dev-python/uritemplate-3.0.0[${PYTHON_USEDEP}]
+"
+# via PyJWT[crypto]
+RDEPEND+="
+	>=dev-python/cryptography-3.3.1[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		>=dev-python/betamax-0.8.0[${PYTHON_USEDEP}]
+		>=dev-python/betamax-matchers-0.3.0[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# betamax / urllib3 problem
+		# upstream marked these tests xfail...
+		# https://github.com/sigmavirus24/github3.py/commit/9d6124c09b0997b5e83579549bcf22b3e901d7e5
+		tests/integration/test_repos_repo.py::TestRepoCommit::test_{diff,patch}
+		tests/integration/test_repos_repo.py::TestComparison::test_{diff,patch}
+	)
+
+	epytest -o addopts=
+}
diff --git a/dev-python/github3-py/metadata.xml b/dev-python/github3-py/metadata.xml
new file mode 100644
index 0000000000000..b418a11910505
--- /dev/null
+++ b/dev-python/github3-py/metadata.xml
@@ -0,0 +1,19 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>python@gentoo.org</email>
+	</maintainer>
+	<maintainer type="person">
+		<email>nicolasbock@gentoo.org</email>
+	</maintainer>
+	<longdescription lang="en">
+		github3.py is wrapper for the GitHub API written in python. The design
+		of github3.py is centered around having a logical organization of the
+		methods needed to interact with the API.
+	</longdescription>
+	<upstream>
+		<remote-id type="github">sigmavirus24/github3.py</remote-id>
+		<remote-id type="pypi">github3.py</remote-id>
+	</upstream>
+</pkgmetadata>