2025-01-31 23:11:16+00:00grafted

3 files changed, 96 insertions, 0 deletions

diff --git a/dev-python/python-ldap/Manifest b/dev-python/python-ldap/Manifest
new file mode 100644
index 0000000000000..0bcdc9eac54c6
--- /dev/null
+++ b/dev-python/python-ldap/Manifest
@@ -0,0 +1,3 @@
+DIST python-ldap-3.4.4.gh.tar.gz 378862 BLAKE2B 05a0f9696b888f56ea51f4cdfc21e3c67b10aec8d1d300c1f6b26d23285d81e7a126e0e56e4a8343a5c1f35c919ef340287dc9109d26ed146e1d64a0831b722b SHA512 de87bc6f64540969d1a0ec003f2518c4e8a1899798085371ed017209702fe0c580eea235def8208a5aea42541011b2515c982924f6a75558a84b3f01785254ae
+EBUILD python-ldap-3.4.4.ebuild 1706 BLAKE2B 2e2b6aac9f9ee179ce4c24287a3049304221b0f8a16680cf794747d647dbf436e645e5ab4b830e6a9b134de68aa2af478efeaf865d9588aeef715fbb87e960cd SHA512 5bb4128eb826fd899877d11445f0f9484dddd952ae3424a6769b030d37510981b2a8130d8f062be00fea8b36ae4c23d1a3399c7bb9c35b48a178c14a28cdd86b
+MISC metadata.xml 449 BLAKE2B 14ffa18ca09eb663d3ef4ff5bd0ebc8511fa408a4e96c93885ba2beaccdf3bb82a9733a01149e088c8b66d6cb938f94fc3940c0c0cca5685599191e772443cb6 SHA512 2f5c014e55f838b84abf6ba630b000620a01e2fca6d1f1bd1b30db309f820df50c2ef7feddc17c69ee0188c3cbc91a388933b4bccfc8d2ea0cb18c6dae85cda6
diff --git a/dev-python/python-ldap/metadata.xml b/dev-python/python-ldap/metadata.xml
new file mode 100644
index 0000000000000..7e001039514c4
--- /dev/null
+++ b/dev-python/python-ldap/metadata.xml
@@ -0,0 +1,13 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>python@gentoo.org</email>
+		<name>Python</name>
+	</maintainer>
+	<upstream>
+		<remote-id type="pypi">python-ldap</remote-id>
+		<remote-id type="github">python-ldap/python-ldap</remote-id>
+		<bugs-to>https://github.com/python-ldap/python-ldap/issues</bugs-to>
+	</upstream>
+</pkgmetadata>
diff --git a/dev-python/python-ldap/python-ldap-3.4.4.ebuild b/dev-python/python-ldap/python-ldap-3.4.4.ebuild
new file mode 100644
index 0000000000000..c77194ddc6334
--- /dev/null
+++ b/dev-python/python-ldap/python-ldap-3.4.4.ebuild
@@ -0,0 +1,80 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( pypy3 python3_{10..12} )
+
+inherit distutils-r1
+
+DESCRIPTION="Various LDAP-related Python modules"
+HOMEPAGE="
+	https://www.python-ldap.org/en/latest/
+	https://pypi.org/project/python-ldap/
+	https://github.com/python-ldap/python-ldap/
+"
+SRC_URI="
+	https://github.com/python-ldap/python-ldap/archive/${P}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+S=${WORKDIR}/${PN}-${P}
+
+LICENSE="MIT PSF-2"
+SLOT="0"
+KEYWORDS="~alpha amd64 arm arm64 ~hppa ~mips ~ppc ppc64 ~riscv sparc x86"
+IUSE="examples sasl ssl"
+
+RDEPEND="
+	>=dev-python/pyasn1-0.3.7[${PYTHON_USEDEP}]
+	>=dev-python/pyasn1-modules-0.1.5[${PYTHON_USEDEP}]
+	net-nds/openldap:=[sasl?,ssl?]
+"
+# We do not link against cyrus-sasl but we use some
+# of its headers during the build.
+DEPEND="
+	net-nds/openldap:=[sasl?,ssl?]
+	sasl? ( >=dev-libs/cyrus-sasl-2.1 )
+"
+
+distutils_enable_tests pytest
+distutils_enable_sphinx Doc
+
+python_prepare_all() {
+	if ! use sasl; then
+		sed -i 's/HAVE_SASL//g' setup.cfg || die
+	fi
+	if ! use ssl; then
+		sed -i 's/HAVE_TLS//g' setup.cfg || die
+	fi
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	# Run all tests which don't require slapd
+	local EPYTEST_IGNORE=(
+		t_bind.py
+		t_cext.py
+		t_edit.py
+		t_ldapobject.py
+		t_ldap_options.py
+		t_ldap_sasl.py
+		t_ldap_schema_subentry.py
+		t_ldap_syncrepl.py
+		t_slapdobject.py
+	)
+	pushd Tests >/dev/null || die
+	epytest
+	popd > /dev/null || die
+}
+
+python_install_all() {
+	if use examples; then
+		docinto examples
+		dodoc -r Demo/.
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+	distutils-r1_python_install_all
+}